GAP (HAP commands) - Chapter 4: Three Manifolds

Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 Bib Ind
[Top of Book] [Contents] [Previous Chapter] [Next Chapter]

[MathJax off]

4 Three Manifolds
4.1 Dehn Surgery
4.2 Connected Sums
4.3 Dijkgraaf-Witten Invariant
4.4 Cohomology rings
4.5 Linking Form
4.6 Determining the homeomorphism type of a lens space
4.7 Surgeries on distinct knots can yield homeomorphic manifolds
4.8 Finite fundamental groups of \(3\)-manifolds

### 4 Three Manifolds

#### 4.1 Dehn Surgery

The following example constructs, as a regular CW-complex, a closed orientable 3-manifold \(W\) obtained from the 3-sphere by drilling out a tubular neighbourhood of a trefoil knot and then gluing a solid torus to the boundary of the cavity via a homeomorphism corresponding to a Dehn surgery coefficient \(p/q=17/16\).

    gap> ap:=ArcPresentation(PureCubicalKnot(3,1));;
    gap> p:=17;;q:=16;;
    gap> W:=ThreeManifoldViaDehnSurgery(ap,p,q);
    Regular CW-complex of dimension 3

The next commands show that this \(3\)-manifold \(W\) has integral homology

\( H_0(W,\mathbb Z)=\mathbb Z\), \( H_1(W,\mathbb Z)=\mathbb Z_{16}\), \( H_2(W,\mathbb Z)=0\), \( H_3(W,\mathbb Z)=\mathbb Z\)

and that the fundamental group \(\pi_1(W)\) is non-abelian.

    gap> Homology(W,0);Homology(W,1);Homology(W,2);Homology(W,3);
    [ 0 ]
    [ 16 ]
    [  ]
    [ 0 ]

    gap> F:=FundamentalGroup(W);;
    gap> L:=LowIndexSubgroupsFpGroup(F,10);;
    gap> List(L,AbelianInvariants);
    [ [ 16 ], [ 3, 8 ], [ 3, 4 ], [ 2, 3 ], [ 16, 43 ], [ 8, 43, 43 ] ]

The following famous result of Lickorish and (independently) Wallace shows that Dehn surgery on knots leads to an interesting range of spaces.

Theorem: Every closed, orientable, connected \(3\)-manifold can be obtained by surgery on a link in \(S^3\). (Moreover, one can always perform the surgery with surgery coefficients \(\pm 1\) and with each individual component of the link unknotted.)

#### 4.2 Connected Sums

The following example constructs the connected sum \(W=A\#B\) of two \(3\)-manifolds, where \(A\) is obtained from a \(5/1\) Dehn surgery on the complement of the first prime knot on 11 crossings and \(B\) is obtained by a \(5/1\) Dehn surgery on the complement of the second prime knot on 11 crossings. The homology groups

\(H_1(W,\mathbb Z) = \mathbb Z_2\oplus \mathbb Z_{594}\), \(H_2(W,\mathbb Z) = 0\), \(H_3(W,\mathbb Z) = \mathbb Z\)

are computed.

    gap> ap1:=ArcPresentation(PureCubicalKnot(11,1));;
    gap> A:=ThreeManifoldViaDehnSurgery(ap1,5,1);;
    gap> ap2:=ArcPresentation(PureCubicalKnot(11,2));;
    gap> B:=ThreeManifoldViaDehnSurgery(ap2,5,1);;
    gap> W:=ConnectedSum(A,B);
    Regular CW-complex of dimension 3

    gap> Homology(W,1);
    [ 2, 594 ]
    gap> Homology(W,2);
    [  ]
    gap> Homology(W,3);
    [ 0 ]

#### 4.3 Dijkgraaf-Witten Invariant

Given a closed connected orientable \(3\)-manifold \(W\), a finite group \(G\) and a 3-cocycle \(\alpha\in H^3(BG,U(1))\) Dijkgraaf and Witten define the complex number

$$ Z^{G,\alpha}(W) = \frac{1}{|G|}\sum_{\gamma\in {\rm Hom}(\pi_1W, G)} \langle \gamma^\ast[\alpha], [M]\rangle \ \in\ \mathbb C\ $$ where \(\gamma\) ranges over all group homomorphisms \(\gamma\colon \pi_1W \rightarrow G\). This complex number is an invariant of the homotopy type of \(W\) and is useful for distinguishing between certain homotopically distinct \(3\)-manifolds.

A homology version of the Dijkgraaf-Witten invariant can be defined as the set of homology homomorphisms $$D_G(W) =\{ \gamma_\ast\colon H_3(W,\mathbb Z) \longrightarrow H_3(BG,\mathbb Z) \}_{\gamma\in {\rm Hom}(\pi_1W, G)}.$$ Since \(H_3(W,\mathbb Z)\cong \mathbb Z\) we represent \(D_G(W)\) by the set \(D_G(W)=\{ \gamma_\ast(1) \}_{\gamma\in {\rm Hom}(\pi_1W, G)}\) where \(1\) denotes one of the two possible generators of \(H_3(W,\mathbb Z)\).

For any coprime integers \(p,q\ge 1\) the lens space \(L(p,q)\) is obtained from the 3-sphere by drilling out a tubular neighbourhood of the trivial knot and then gluing a solid torus to the boundary of the cavity via a homeomorphism corresponding to a Dehn surgery coefficient \(p/q\). Lens spaces have cyclic fundamental group \(\pi_1(L(p,q))=C_p\) and homology \(H_1(L(p,q),\mathbb Z)\cong \mathbb Z_p\), \(H_2(L(p,q),\mathbb Z)\cong 0\), \(H_3(L(p,q),\mathbb Z)\cong \mathbb Z\). It was proved by J.H.C. Whitehead that two lens spaces \(L(p,q)\) and \(L(p',q')\) are homotopy equivalent if and only if \(p=p'\) and \(qq'\equiv \pm n^2 \bmod p\) for some integer \(n\).

The following session constructs the two lens spaces \(L(5,1)\) and \(L(5,2)\). The homology version of the Dijkgraaf-Witten invariant is used with \(G=C_5\) to demonstrate that the two lens spaces are not homotopy equivalent.

    gap> ap:=[[2,1],[2,1]];; #Arc presentation for the trivial knot

    gap> L51:=ThreeManifoldViaDehnSurgery(ap,5,1);;
    gap> D:=DijkgraafWittenInvariant(L51,CyclicGroup(5));
    [ g1^4, g1^4, g1, g1, id ]

    gap> L52:=ThreeManifoldViaDehnSurgery(ap,5,2);;
    gap> D:=DijkgraafWittenInvariant(L52,CyclicGroup(5));
    [ g1^3, g1^3, g1^2, g1^2, id ]

A theorem of Fermat and Euler states that if a prime \(p\) is congruent to 3 modulo 4, then for any \(q\) exactly one of \(\pm q\) is a quadratic residue mod p. For all other primes \(p\) either both or neither of \(\pm q\) is a quadratic residue mod \(p\). Thus for fixed \(p \equiv 3 \bmod 4\) the lens spaces \(L(p,q)\) form a single homotopy class. There are precisely two homotopy classes of lens spaces for other \(p\).

The following commands confirm that \(L(13,1) \not\simeq L(13,2)\).

    gap> L13_1:=ThreeManifoldViaDehnSurgery([[1,2],[1,2]],13,1);;
    gap> DijkgraafWittenInvariant(L13_1,CyclicGroup(13));
    [ g1^12, g1^12, g1^10, g1^10, g1^9, g1^9, g1^4, g1^4, g1^3, g1^3, g1, g1, id ]
    gap> L13_2:=ThreeManifoldViaDehnSurgery([[1,2],[1,2]],13,2);;
    gap> DijkgraafWittenInvariant(L13_2,CyclicGroup(13));
    [ g1^11, g1^11, g1^8, g1^8, g1^7, g1^7, g1^6, g1^6, g1^5, g1^5, g1^2, g1^2,
      id ]

#### 4.4 Cohomology rings

The following commands construct the multiplication table (with respect to some basis) for the cohomology rings \(H^\ast(L(13,1),\mathbb Z_{13})\) and \(H^\ast(L(13,2),\mathbb Z_{13})\). These rings are isomorphic and so fail to distinguish between the homotopy types of the lens spaces \(L(13,1)\) and \(L(13,2)\).

    gap> L13_1:=ThreeManifoldViaDehnSurgery([[1,2],[1,2]],13,1);;
    gap> L13_2:=ThreeManifoldViaDehnSurgery([[1,2],[1,2]],13,2);;
    gap> L13_1:=BarycentricSubdivision(L13_1);;
    gap> L13_2:=BarycentricSubdivision(L13_2);;
    gap> A13_1:=CohomologyRing(L13_1,13);;
    gap> A13_2:=CohomologyRing(L13_2,13);;
    gap> M13_1:=List([1..4],i->[]);;
    gap> B13_1:=CanonicalBasis(A13_1);;
    gap> M13_2:=List([1..4],i->[]);;
    gap> B13_2:=CanonicalBasis(A13_2);;
    gap> for i in [1..4] do
    > for j in [1..4] do
    > M13_1[i][j]:=B13_1[i]*B13_1[j];
    > od;od;
    gap> for i in [1..4] do
    > for j in [1..4] do
    > M13_2[i][j]:=B13_2[i]*B13_2[j];
    > od;od;
    gap> Display(M13_1);
    [ [            v.1,            v.2,            v.3,            v.4 ],
      [            v.2,          0*v.1,  (Z(13)^6)*v.4,          0*v.1 ],
      [            v.3,  (Z(13)^6)*v.4,          0*v.1,          0*v.1 ],
      [            v.4,          0*v.1,          0*v.1,          0*v.1 ] ]
    gap> Display(M13_2);
    [ [          v.1,          v.2,          v.3,          v.4 ],
      [          v.2,        0*v.1,  (Z(13))*v.4,        0*v.1 ],
      [          v.3,  (Z(13))*v.4,        0*v.1,        0*v.1 ],
      [          v.4,        0*v.1,        0*v.1,        0*v.1 ] ]

#### 4.5 Linking Form

Given a closed connected oriented \(3\)-manifold \(W\) let \(\tau H_1(W,\mathbb Z)\) denote the torsion subgroup of the first integral homology. The linking form is a bilinear mapping

\(Lk_W\colon \tau H_1(W,\mathbb Z) \times \tau H_1(W,\mathbb Z) \longrightarrow \mathbb Q/\mathbb Z\).

To construct this form note that we have a Poincare duality isomorphism

\(\rho\colon H^2(W,\mathbb Z) \stackrel{\cong}{\longrightarrow} H_1(W,\mathbb Z), z \mapsto z\cap [W]\)

involving the cap product with the fundamental class \([W]\in H^3(W,\mathbb Z)\). That is, \([M]\) is the generator of \(H^3(W,\mathbb Z)\cong \mathbb Z\) determining the orientation. The short exact sequence \(\mathbb Z \rightarrowtail \mathbb Q \twoheadrightarrow \mathbb Q/\mathbb Z\) gives rise to a cohomology exact sequence

\( \rightarrow H^1(W,\mathbb Q) \rightarrow H^1(W,\mathbb Q/\mathbb Z) \stackrel{\beta}{\longrightarrow} H^2(W,\mathbb Z) \rightarrow H^2(W,\mathbb Q) \rightarrow \)

from which we obtain the isomorphism \(\beta \colon \tau H^1(W,\mathbb Q/\mathbb Z) \stackrel{\cong}{\longrightarrow} \tau H^2(W,\mathbb Z)\). The linking form \(Lk_W\) can be defined as the composite

\(Lk_W\colon \tau H_1(W,\mathbb Z) \times \tau H_1(W,\mathbb Z) \stackrel{1\times \rho^{-1}}{\longrightarrow} \tau H_1(W,\mathbb Z) \times \tau H^2(W,\mathbb Z) \stackrel{1\times \beta^{-1}}{\longrightarrow} \tau H_1(W,\mathbb Z) \times \tau H^1(W,\mathbb Q/\mathbb Z) \stackrel{ev}{\longrightarrow } \mathbb Q/\mathbb Z \)

where \(ev(x,\alpha)\) evaluates a \(1\)-cocycle \(\alpha\) on a \(1\)-cycle \(x\).

The linking form can be used to define the set

\(I^O(W) = \{Lk_W(g,g) \ \colon \ g\in \tau H_1(W,\mathbb Z)\}\)

which is an oriented-homotopy invariant of \(W\). Letting \(W^+\) and \(W^-\) denote the two possible orientations on the manifold, the set

\(I(W) =\{I^O(W^+), I^O(W^-)\}\)

is a homotopy invariant of \(W\) which in this manual we refer to as the linking form homotopy invariant.

The following commands compute the linking form homotopy invariant for the lens spaces \(L(13,q)\) with \(1\le q\le 12\). This invariant distinguishes between the two homotopy types that arise.

    gap> LensSpaces:=[];;
    gap> for q in [1..12] do
    > Add(LensSpaces,ThreeManifoldViaDehnSurgery([[1,2],[1,2]],13,q));
    > od;
    gap> Display(List(LensSpaces,LinkingFormHomotopyInvariant));;
    [ [ [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ],
          [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ] ],

      [ [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ], [ 0, 2/13,
              2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ] ],

      [ [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ],
          [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ] ],

      [ [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ],
          [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ] ],

      [ [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ],
          [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ] ],

      [ [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ],
          [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ] ],

      [ [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ],
          [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ] ],

      [ [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ],
          [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ] ],

      [ [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ],
          [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ] ],

      [ [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ],
          [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ] ],

      [ [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ],
          [ 0, 2/13, 2/13, 5/13, 5/13, 6/13, 6/13, 7/13, 7/13, 8/13, 8/13, 11/13, 11/13 ] ],

      [ [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ],
          [ 0, 1/13, 1/13, 3/13, 3/13, 4/13, 4/13, 9/13, 9/13, 10/13, 10/13, 12/13, 12/13 ] ] ]

#### 4.6 Determining the homeomorphism type of a lens space

In 1935 K. Reidemeister [Rei35] classified lens spaces up to orientation preserving PL-homeomorphism. This was generalized by E. Moise [Moi52] in 1952 to a classification up to homeomorphism -- his method requred the proof of the Hauptvermutung for \(3\)-dimensional manifolds. In 1960, following a suggestion of R. Fox, a proof was given by E.J. Brody [Bro60] that avoided the need for the Hauptvermutung. Reidemeister's method, using what is know termed Reidermeister torsion, and Brody's method, using tubular neighbourhoods of \(1\)-cycles, both require identifying a suitable "preferred" generator of \(H_1(L(p,q),\mathbb Z)\). In 2003 J. Przytycki and A. Yasukhara [PY03] provided an alternative method for classifying lens spaces, which uses the linking form and again requires the identification of a "preferred" generator of \(H_1(L(p,q),\mathbb Z)\).

Przytycki and Yasukhara proved the following.

Theorem. Let \(\rho\colon S^ 3 \rightarrow L(p, q)\) be the \(p\)-fold cyclic cover and \(K\) a knot in \(L(p, q)\) that represents a generator of \(H_1 (L(p, q), \mathbb Z)\). If \(\rho ^{-1} (K)\) is the trivial knot, then \(Lk_{ L(p,q)} ([K], [K]) = q/p\) or \(= \overline q/p \in \mathbb Q/\mathbb Z\) where \(q\overline q \equiv 1 \bmod p\).

The ingredients of this theorem can be applied in HAP, but at present only to small examples of lens spaces. The obstruction to handling large examples is that the current default method for computing the linking form involves barycentric subdivision to produce a simplicial complex from a regular CW-complex, and then a homotopy equivalence from this typically large simplicial complex to a smaller non-regular CW-complex. However, for homeomorphism invariants that are not homotopy invariants there is a need to avoid homotopy equivalences. In the current version of HAP this means that in order to obtain delicate homeomorphism invariants we have to perform homology computations on typically large simplicial complexes. In a future version of HAP we hope to avoid the obstruction by implementing cup products, cap products and linking forms entirely within the category of regular CW-complexes.

The following commands construct a small lens space \(L=L(p,q)\) with unknown values of \(p,q\). Subsequent commands will determine the homeomorphism type of \(L\).

    gap> p:=Random([2,3,5,7,11,13,17]);;
    gap> q:=Random([1..p-1]);;
    gap> L:=ThreeManifoldViaDehnSurgery([[1,2],[1,2]],p,q);
    Regular CW-complex of dimension 3

We can readily determine the value of \(p=11\) by calculating the order of \(\pi_1(L)\).

    gap> F:=FundamentalGroupWithPathReps(L);;
    gap> StructureDescription(F);
    "C11"

The next commands take the default edge path \(\gamma\colon S^1\rightarrow L\) representing a generator of the cyclic group \(\pi_1(L)\) and lift it to an edge path \(\tilde\gamma\colon S^1\rightarrow \tilde L\).

    gap> U:=UniversalCover(L);;
    gap> G:=U!.group;;
    gap> p:=EquivariantCWComplexToRegularCWMap(U,Group(One(G)));;
    gap> U:=Source(p);;
    gap> gamma:=[];;
    gap> gamma[2]:=F!.loops[1];;
    gap> gamma[2]:=List(gamma[2],AbsInt);;
    gap> gamma[1]:=List(gamma[2],k->L!.boundaries[2][k]);;
    gap> gamma[1]:=SSortedList(Flat(gamma[1]));;
    gap>
    gap> gammatilde:=[[],[],[],[]];;
    gap> for k in [1..U!.nrCells(0)] do
    > if p!.mapping(0,k) in gamma[1] then Add(gammatilde[1],k); fi;
    > od;
    gap> for k in [1..U!.nrCells(1)] do
    > if p!.mapping(1,k) in gamma[2] then Add(gammatilde[2],k); fi;
    > od;
    gap> gammatilde:=CWSubcomplexToRegularCWMap([U,gammatilde]);
    Map of regular CW-complexes

The next commands check that the path \(\tilde\gamma\) is unknotted in \(\tilde L\cong S^3\) by checking that \(\pi_1(\tilde L\setminus {\rm image}(\tilde\gamma))\) is infinite cyclic.

    gap> C:=RegularCWComplexComplement(gammatilde);
    Regular CW-complex of dimension 3

    gap> G:=FundamentalGroup(C);
    <fp group of size infinity on the generators [ f2 ]>

Since \(\tilde\gamma\) is unkotted the cycle \(\gamma\) represents the preferred generator \([\gamma]\in H_1(L,\mathbb Z)\). The next commands compute \(Lk_L([\gamma],[\gamma])= 7/11 \).

    gap> LinkingFormHomeomorphismInvariant(L);
    [ 7/11 ]

The classification of Moise/Brody states that \(L(p,q)\cong L(p,q')\) if and only if \(qq'\equiv \pm 1 \bmod p\). Hence the lens space \(L\) has the homeomorphism type

\(L\cong L(11,7) \cong L(11,8) \cong L(11,4) \cong L(11,3)\).

#### 4.7 Surgeries on distinct knots can yield homeomorphic manifolds

The lens space \(L(5,1)\) is a quotient of the \(3\)-sphere \(S^3\) by a certain action of the cyclic group \(C_5\). It can be realized by a \(p/q=5/1\) Dehn filling of the complement of the trivial knot. It can also be realized by Dehn fillings of other knots. To see this, the following commands compute the manifold \(W\) obtained from a \(p/q=1/5\) Dehn filling of the complement of the trefoil and show that \(W\) at least has the same integral homology and same fundamental group as \(L(5,1)\).

    gap> ap:=ArcPresentation(PureCubicalKnot(3,1));;
    gap> W:=ThreeManifoldViaDehnSurgery(ap,1,5);;
    gap> Homology(W,1);
    [ 5 ]
    gap> Homology(W,2);
    [  ]
    gap> Homology(W,3);
    [ 0 ]

    gap> F:=FundamentalGroup(W);;
    gap> StructureDescription(F);
    "C5"

The next commands construct the universal cover \(\widetilde W\) and show that it has the same homology as \(S^3\) and trivivial fundamental group \(\pi_1(\widetilde W)=0\).

    gap> U:=UniversalCover(W);;
    gap> G:=U!.group;;
    gap> Wtilde:=EquivariantCWComplexToRegularCWComplex(U,Group(One(G)));
    Regular CW-complex of dimension 3

    gap> Homology(Wtilde,1);
    [  ]
    gap> Homology(Wtilde,2);
    [  ]
    gap> Homology(Wtilde,3);
    [ 0 ]

    gap> F:=FundamentalGroup(Wtilde);
    <fp group on the generators [  ]>

By construction the space \(\widetilde W\) is a manifold. Had we not known how the regular CW-complex \(\widetilde W\) had been constructed then we could prove that it is a closed \(3\)-manifold by creating its barycentric subdivision \(K=sd\widetilde W\), which is homeomorphic to \(\widetilde W\), and verifying that the link of each vertex in the simplicial complex \(sd\widetilde W\) is a \(2\)-sphere. The following commands carry out this proof: each link is shown to admit a discrete vector field with precisely two critical cells -- one \(0\)-cell and one \(2\)-cell.

    gap> K:=BarycentricSubdivision(Wtilde);
    Simplicial complex of dimension 3.

    gap> L:=[];;
    gap> for v in K!.vertices do
    > Add(L,CriticalCells(RegularCWComplex(VertexLink(K,v))));
    > od;
    gap> SSortedList(List(L,Size));
    [ 2 ]
    gap> C:=Concatenation(L);;
    gap> SSortedList(List(C,x->x[1]));
    [ 0, 2 ]

The Poincare conjecture (now proven) implies that \(\widetilde W\) is homeomorphic to \(S^3\). Hence \(W=S^3/C_5\) is a quotient of the \(3\)-sphere by an action of \(C_5\) and is hence a lens space \(L(5,q)\) for some \(q\).

The next commands determine that \(W\) is homeomorphic to \(L(5,4)\cong L(5,1)\).

    gap> Lk:=LinkingFormHomeomorphismInvariant(W);
    [ 0, 4/5 ]

Moser [Mos71] gives a precise decription of the lens spaces arising from surgery on the trefoil knot and more generally from surgery on torus knots. Greene [Gre13] determines the lens spaces that arise by integer Dehn surgery along a knot in the three-sphere

#### 4.8 Finite fundamental groups of \(3\)-manifolds

Lens spaces are examples of \(3\)-manifolds with finite fundamental groups. The complete list of finite groups \(G\) arising as fundamental groups of closed connected \(3\)-manifolds is recalled in 7.11 where one method for computing their cohomology rings is presented. Their cohomology could also be computed from explicit \(3\)-manifolds \(W\) with \(\pi_1W=G\). For instance, the following commands realize a closed connected \(3\)-manifold \(W\) with \(\pi_1W = C_{11}\times SL_2(\mathbb Z_5)\).

    gap> ap:=ArcPresentation(PureCubicalKnot(3,1));;
    gap> W:=ThreeManifoldViaDehnSurgery(ap,1,11);;
    gap> F:=FundamentalGroup(W);;
    gap> Order(F);
    1320
    gap> AbelianInvariants(F);
    [ 11 ]
    gap> StructureDescription(F);
    "C11 x SL(2,5)"

Hence the group \(G=C_{11}\times SL_2(\mathbb Z_5)\) of order \(1320\) acts freely on the \(3\)-sphere \(\widetilde W\). It thus has periodic cohomology with

\[ H_n(G,\mathbb Z) = \left\{ \begin{array}{ll} \mathbb Z_{11} & n\equiv 1 \bmod 4 \\ 0 & n\equiv 2 \bmod 4 \\ \mathbb Z_{1320} & n \equiv 3\bmod 4\\ \mathbb 0 & n\equiv 0 \bmod 4 \\ \end{array}\right. \]

for \(n > 0\).

[Top of Book] [Contents] [Previous Chapter] [Next Chapter]
Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 Bib Ind

generated by GAPDoc2HTML